require recipes-kernel/linux/linux-yocto.inc

FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
SRC_URI += " file://linux-imx-lf-6.18.20-2.0.0.patch "
PATCHTOOL = "patch"

KERNEL_DANGLING_FEATURES_WARN_ONLY="1"
KERNEL_DTC_FLAGS = "-@"
KERNEL_DTOVERLAY ?= ""

do_copy_defconfig:append() {
    if [ "${TARGET_ARCH}" = "arm" ]; then
        cp ${S}/arch/arm/configs/${MACHINE}_defconfig ${WORKDIR}/defconfig
        cp ${S}/arch/arm/configs/${MACHINE}_defconfig ${B}/.config
    else
        cp ${S}/arch/arm64/configs/${MACHINE}_defconfig ${WORKDIR}/defconfig
        cp ${S}/arch/arm64/configs/${MACHINE}_defconfig ${B}/.config
    fi
}

do_compile:append() {
    if [ -n "${KERNEL_DTC_FLAGS}" ]; then
        export DTC_FLAGS="${KERNEL_DTC_FLAGS}"
    fi

    for dtbf in ${KERNEL_DTOVERLAY}; do
        dtb=`normalize_dtb "$dtbf"`
        oe_runmake $dtb CC="${KERNEL_CC} $cc_extra " LD="${KERNEL_LD}" ${KERNEL_EXTRA_ARGS}
    done
}

do_deploy:append(){
    install -d ${DEPLOYDIR}/overlays

    if [ "${TARGET_ARCH}" = "arm" ]; then
        dtbo_path="${B}/arch/arm/boot/dts/nxp/imx/${MACHINE}"
    else
        dtbo_path="${B}/arch/arm64/boot/dts/freescale/${MACHINE}"
    fi

    cp $dtbo_path/*.dtbo ${DEPLOYDIR}/overlays/
}