/***********************************************************************
 *        File:  led.S
 *     Version:  1.0.0
 *   Copyright:  2013 (c) Guo Wenxue <guowenxue@gmail.com>
 * Description:  This ASM code used to turn LED0~LED4 on/off on OK6410 board
 *   ChangeLog:  1, Release initial version on "Sun Feb 24 15:06:12 CST 2013"
 *
 ***********************************************************************/


#define SROM_BW  0x70000000
#define WTCON    0x7E004000
#define GPMCON   0x7F008820
#define GPMDAT   0x7F008824
#define GPMUP    0x7F008828

#define OUTPUT   0x01   /*Set GPIO port as output mode*/
#define INPUT    0x00   /*Set GPIO port as input mode*/

#define LED1     0      /*On OK6410 board, LED1 use GPM1*/
#define LED2     1      /*On OK6410 board, LED2 use GPM0*/
#define LED3     2      /*On OK6410 board, LED3 use GPM2*/
#define LED4     3      /*On OK6410 board, LED4 use GPM3*/


#define DELAY    0X1000000 /*TEXTBASE = 0x57e00000, we have init CPU to 533MHz*/
//#define DELAY    0X10000   /*TEXTBASE = 0x0C000000, we havn't init CPU CLOCK*/

    .global _start

_start:
    /* Peri port setup */
    ldr     r0, =SROM_BW
    orr     r0, r0, #0x13
    mcr     p15,0,r0,c15,c2,4       @ 256M(0x70000000-0x7fffffff)

    /* Disable watchdog */
    ldr     r0, =WTCON
    mov     r1, #0
    str     r1, [r0]

    /*Set GPM0, GPM1, GPM2, GPM3 as GPIO OUTPUT mode*/
    ldr     r0, =GPMCON
    bic     r1, r1, #0x00FF     /*Set GPMCON for GPM0,GPM1 as 0x00 */
    orr     r1, r1, #0x0011     /*Set GPMCON for GPM0,GPM1 as GPIOOUT, 0x01*/
    bic     r1, r1, #0xFF00     /*Set GPMCON for GPM2,GPM3 as 0x00*/
    orr     r1, r1, #0x1100     /*Set GPMCON for GPM2,GPM3 as GPIOOUT, 0x01*/
    str     r1, [r0]

loopled:
    /*Turn off LED1, LED2, LED3, LED4*/
    ldr     r0, =GPMDAT
    ldr     r1, [r0]
    orr     r1, r1, #0xF         /*Set bit[0:3] as high level*/
    str     r1, [r0]  
    bl      delay

    /*Turn on LED1*/
    ldr     r1, [r0]
    bic     r1, r1, #(1<<LED1)  /*LED1 GPIO port as low level*/
    str     r1, [r0]  
    bl      delay

    /*Turn on LED2*/
    ldr     r1, [r0]
    bic     r1, r1, #(1<<LED2)  /*LED2 GPIO port as low level*/
    str     r1, [r0]  
    bl      delay

    /*Turn on LED3*/
    ldr     r1, [r0]
    bic     r1, r1, #(1<<LED3)  /*LED3 GPIO port as low level*/
    str     r1, [r0]  
    bl      delay

    /*Turn on LED4*/
    ldr     r1, [r0]
    bic     r1, r1, #(1<<LED4)  /*LED4 GPIO port as low level*/
    str     r1, [r0]  
    bl      delay

    b       loopled             /*Loop running LED*/

delay:
    mov     r2, #DELAY
delay_loop:
    sub     r2, r2,#1
    cmp     r2, #0
    bne     delay_loop
    mov     pc, lr 
    
halt:
    b       halt